Программа воспроизведения произвольного звукового файла с использованием звукового адаптера (формат - wav)

Примечаниеот редактора: работа опубликована без программы
Загрузить архив:
Файл: ref-26913.zip (34kb [zip], Скачиваний: 77) скачать
; wavdma

Федеральное агентство по науке и образованию

Российской Федерации.

Брянский государственный технический университет.

Кафедра информатики и программного обеспечения.

Курсовая работа

по дисциплине

 «Организация ЭВМ»

на тему:

«Программа воспроизведения произвольного звукового файла с использованием звукового адаптера (формат - wav)».

                                                                                     Студент:

                                                                                                Изотов  И.Н.

                                                                           Группа:

                                                                             06ПО3(с)

                                                                                              Преподаватель:

                                                                                                      Статутов А.Г.      

Брянск 2018

Содержание

стр.

Введение--------------------------------------------------------------------------------------- 3

Устройство звуковой платы  Sound Blaster--------------------------------------------- 4

Программирование DSP-------------------------------------------------------------------- 5

Команды DSP--------------------------------------------------------------------------------- 7

Программирование  контроллера DMA------------------------------------------------ 12

Описание функции Open_file------------------------------------------------------------- 17

Алгоритм и блок-схема-------------------------------------------------------------------- 18

Компиляция---------------------------------------------------------------------------------- 19

Код исходной  программы(начало)----------------------------------------------------- 20

Заключение---------------------------------------------------------------------------------- 25

Литература----------------------------------------------------------------------------------- 26

Введение

Программирование современных звуковых плат - весьма сложное занятие. В качестве примера рассмотрим одну часто применяемую операцию – воспроизведение оцифрованного звука. Для вывода звука через звуковую плату может использоваться один из трех режимов: пряной вывод (команда 10h), когда программа должна сама с нужной частотой посылать отдельные байты из оцифрованного звука в DSP; простой DMA-режим, когда выводится блок данных, после чего вызывается прерывания; и DMA с автоинициализацией, когда данные выводятся непрерывно и после вызова каждого блока вызывается прерывание. Именно в этом  порядке увеличивается качество воспроизводимого звука. В первом случаи качество звука будет очень плохим, поэтому будем реализовывать второй случай, благодаря чему мы сможем указать точную скорость оцифровки звука и выводить 16-битный звук.  Данная программа работает только на звуковых платах  Sound Blaster.

 

Устройство звуковой платы  Sound Blaster

Звуковые платы совместимые с теми или иными моделями Sound Blaster, выглядят как четыре независимых устройства:

1) DSP (Digital Signal Processor) - устройство, позволяющее выводить и счи­тывать оцифрованный звук;

2)  Микшер (Mixer) - система регуляторов громкости для всех каналов платы;

3) DFM (Frequency Modulation) или AdLib (по названию первой звуковой пла­ты) - устройство, позволяющее синтезировать звук из синусоидальных и треугольных волн. Слова типа OPL2 или OPL3 в описании платы - это и есть номера версии используемого FM-синтезатора;

4)  MIDI (Music Instrumental Digital Interface) - стандартный интерфейс пере­дачи данных в музыкальной аппаратуре. Но в нашем случае рассматривает­ся GMIDI (обобщенный MIDI) - более качественная система генерации му­зыки, в которой используются не искусственные синусоидальные сигналы, а образцы звучания различных инструментов. К сожалению, качество этих образцов в большинстве дешевых плат оставляет желать лучшего.

Номера портов ввода-вывода, предоставляющих доступ ко всем этим устрой­ствам, отсчитываются от базового порта, обычно равного 220h, но допускаются также конфигурации с 210h, 230h, 240h, 250h, 260h и 280h. Кроме того, интерфейс - GMIDI использует другую серию портов, которая может начинаться как с 300h, так и с 330h. В описаниях портов мы будем считать, что базовыми являются 220U и 300h. Область портов интерфейса с AdLib начинается с 388h.

Существует большое число модификаций плат Sound Blaster, отличающихся, помимо всего прочего, набором поддерживаемых команд и портов ввода-вывода. После названия каждой команды или порта мы будем указывать сокращенное название платы, начиная с которой эта команда или порт поддерживается:

-  SB- Sound Blaster 1.0;

 - SB2 - Sound Blaster 2.0;

-  SBPro - Sound Blaster Pro;

-  SBPro2 - Sound Blaster Pro2;

-  SB16 - Sound Blaster 16;

-  ASP - Sound Blaster 16 ASP;

-  AWE - Sound Blaster AWE32.

Программирование DSP

Цифровой процессор - наиболее важная часть звуковой платы. Именно с его помощью осуществляется вывод обычного оцифрованного звука, так же как и за­пись звука из внешнего источника в файл. Для своей работы, помимо описывае­мых в этом разделе портов, DSP использует прерывания и контроллер прямого доступа к памяти DMA. Программирование DMA мы рассмотрим далее. DSP обслуживается при помощи следующих портов:

226h для записи: сброс DSP (SB)

Запись в этот порт осуществляет полную переинициализацию DSP, прерывая все происходящие процессы. Операцию сброса DSP необходимо выполнить, по крайней мере, один раз после перезагрузки системы, чтобы его можно было использовать.

Процедура сброса осуществляется следующим образом:

1.    В порт 226h записывается число 1 (начало инициализации).

2.    Выдерживается пауза как минимум 3,3 мкс.

3.    В порт 226h записывается число 0 (конец инициализации).

4.  Выдерживается пауза максимум 100 мкс. В течение паузы можно выполнять чтение порта 22Eh. Когда в считываемом числе будет установлен бит 7 (дан­ные готовы), можно сразу переходить к пункту 5. В противном случае имеет смысл повторить процедуру, используя другой базовый порт.

5.  Выполняется чтение из порта 22Ah. Если считанное число равно 0AAh - DSP был успешно инициализирован. В противном случае допускается вернуться к пункту 4, но по истечении 100 мкс после записи в 226h можно будет с уверен­ностью сказать, что DSP с базовым адресом 220h не существует или не работает.

22Ah для чтения: чтение данных из DSP (SB)

Чтение из этого порта используется для передачи всех  возможных данных от DSP программам. Процедура чтения состоит из двух шагов;

1.  Выполнять цикл чтения порта 22Eh, пока бит 7 считываемого байта не ока­жется равным единице.

2.   Выполнить чтение из порта 22Ah.

22CН для записи: запись данных и команд DSP (начиная с SB)

Этот единственный порт используется для передачи всего множества команд DSP и для пересылки в него данных (аргументов команд). Процедура записи:

1. Выполнять цикл чтения порта 22Ch, пока бит 7 считываемого байта не ока­жется равным нулю.

2.  Выполнить запись в порт 22Ch.

22Ch для чтения: готовность DSP для приема команды (SB)

Если при чтении из этого порта бит 7 сброшен в ноль - DSP готов к приему оче­редного байта в порт 22Ch на запись. Значение остальных битов не определено.

22Eh для чтения: готовность DSP для посылки данных (начиная с SB)

Если при чтении из этого порта бит 7 установлен в единицу - DSP готов к пере­даче через порт 22Ah очередного байта.

22Eh для чтения (тот же порт!): подтверждение обработки 8-битного прерыва­ния (SB)

Обработчик прерывания, сгенерированного звуковой платой по окончании 8-битной операции, обязательно должен выполнить одно чтение из этого порта перед завершением (помимо обычной процедуры посылки сигнала EOI в соответ­ствующий контроллер прерываний).

22Fh для чтения: подтверждение обработки 16-битного прерывания (SB16)

Обработчик прерывания, сгенерированного звуковой платой по окончании 16-битной операции, обязательно должен выполнить одно чтение из этого пор­та перед завершением (помимо обычной процедуры посылки сигнала ЕОI в со­ответствующий контроллер прерываний).

Теперь рассмотрим команды DSP. Все они пересылаются в звуковую плату че­рез порт 22Ch, как описано выше. После команды могут следовать аргументы которые передаются таким же образом (включая ожидание готовности к приему команды).

Команды DSP

04h: состояние DSP (устаревшая) (SB2 - SBPro2)

Возвращает информацию о текущей операции DSP:

бит 0: динамик включен

бит 1: стерео АЦП включен

бит 2: всегда 0

бит 3: происходит прямое воспроизведение 8-битного РСМ

бит 4: происходит воспроизведение 2-битного ADPCM через DMA

бит 5: происходит воспроизведение 2,6-битного ADPCM через DMA

бит 6: происходит воспроизведение 4-битного ADPCM через DMA

бит 7: происходит воспроизведение 8-битного РСМ через DMA

10h, NN: прямое воспроизведение 8-бйтного звука (SB)

Выводит очередной байт (NN) из несжатого 8-битного оцифрованного звука на воспроизведение. При использовании этого способа воспроизведения сама про­грамма должна заботиться о том, чтобы новые данные всегда были наготове (то есть не считывать их с диска в ходе работы) и чтобы байты пересылались в DSP с необходимой частотой. (В этом режиме поддерживаются частоты до 23 кГц.) Процедура вывода проста:

1.         Вывести в DSP команду 10h и очередной байт из оцифровки.

2.        Подождать необходимое время и вернуться к пункту 1.

Чтобы выполнять пересылку байтов с заданной частотой, обычно перепрог­раммируют системный таймер. Но из-за ограничений по качеству звука и высокой ресурсоемкости такой способ вос­произведения практически не используется.

14h, LO , HI: прямое воспроизведение 8-битного РСМ через DMA (SB). Начинает процесс воспроизведения данных, на которые настроен соответствую­щий канал DMA :

1. Установить обработчик прерывания от звуковой платы (и разрешить его в контроллере прерываний).

2.    Выполнить команду 40h или другим образом установить частоту оцифровки.

3.    Выполнить команду ODlh (включить динамик).

4.    Настроить DMA (режим 48h + номер канала).

5.   Выполнить команду 14h. Аргументы LO и HI - это младший и старший бай­ты длины проигрываемого участка минус один.

6.   Из обработчика прерывания подтвердить его чтением порта 22Е h и посылкой байта 20h в соответствующий контроллер прерываний.

7.      Выполнить команду 0D3h (выключить динамик).

На платах, начиная с SB16, для этого режима рекомендуется пользоваться командами 0C?h.

16h, LO, HI: прямое воспроизведение 2-битного ADPCM через DMA (SB). Начинает процесс воспроизведения данных аналогично команде 14h, но они долж­ны храниться в сжатом формате Creative ADPCM 2 bit. Длина, указываемая в каче­стве аргументов этой команды, равна (число_6айтов + 2)/4. В качестве нулевого байта в процедуре распаковки ADPCM используется значение, которое применя­лось последней командой 17h. В остальном процедура воспроизведения аналогич­на команде 1 Ah.

17h, LO, HI: прямое воспроизведение 2-битного ADPCM через DMA с новым ну­левым бантом (SB).

То же самое, что и 16h, но первый байт из данных будет рассматриваться как ну­левой байт для процедуры распаковки ADPCM.

1Ch: воспроизведение 8-битного PСМ через DMA с автоинициализацией (SB2) Начинает режим воспроизведения с автоинициализацией - лучший из режимов, предлагаемых звуковыми платами. В этом режиме DSP воспроизводит в цикле содержимое указанного участка памяти, мгновенно возвращаясь на начало, пока он не будет остановлен командой 0DAh или новой командой воспроизведения через DMA. Весь секрет заключается в том, что плата генерирует прерывание не только при достижении конца блока, но и при достижении его середины. Таким образом, пока DSP проигрывает вторую половину буфера, мы можем прочитать следующие несколько килобайтов в первую половину, не останавливая воспроиз­ведение ни на миг:

1.

    контроллере прерываний.

2.        Выполнить команду 40h или другим образом установить частоту оцифровки.

3.        Выполнить команду 48h (установить размер DMA-буфера - (число байтов +    

               1)/2 - 1).

4.        Выполнить команду 0Dlh (включить динамик).

5.        Настроить DMA (режим 58h + номер канала).

6.        Выполнить команду 1Ch

7.        В обработчике прерывания: заполнить следующую половину буфера.

8.        В обработчике прерывания: подтвердить прерывание чтением из 22Eh и 

                записью 20h в контроллер прерываний.

9.        Подождать, пока не будут воспроизведены все данные.

10.      Выполнить команду 0D3h (выключить динамик).

11.      Выполнить команду 0D0h (остановить 8-битную DMA-передачу).

12.         Выполнить команду 0DAh (завершить режим автоннициалиэации).

13.         Выполнить команду 0D0h (остановить 8-битную DMA-передачу).

На платах, начиная с SB16, для этого режима рекомендуется пользоваться ко­мандами 0С? h.  

1Fb: воспроизведение 2-битного ADPCM через DMA с автоинициализацией (SB2)

Аналог команды 1Ch, но данные хранятся в 2-битном формате ADPCM с нуле­вым байтом. Длина блока рассчитывается так: длина = (число байтов + 3)/4 + 1 длина блока = (длина + 1)/2 - 1

20h: прямое чтение 8-битных данных из АЦП (SB)

Команда предназначена для чтения оцифрованного звука из внешнего источни­ка. Используется следующая процедура:

1.         Выполнить команду 20h.

2.         Прочитать очередной байт.

3.        Подождать необходимое время и вернуться к пункту 1

Проблемы с этой командой точно такие же, как и с 10h.

24h, LO, HI: чтение 8-битного РСМ через DMA (SB)

Аналог команды 14h, но выполняет не воспроизведение, а запись звука. Последо­вательность действий идентична случаю с 14h, но используемый режим DMA -44h + номер канала.

2Ch: запись 8-бнтного РСМ через DМА с автоинициализацией (SB2) Аналог команды 1Ch, но выполняет не воспроизведении, а запись звука. Последо­вательность действий идентична случаю с 1Ch, но используемый режим DMA -54h + номер канала.

30h: прямое чтение MIDI (SB)

Выполняет чтение очередного MIDI-события:

1.       Выполнить команду З0h.

2.        Прочитать MIDI-событие (до 64 байт).

31h: чтение MIDI с прерыванием (SB)

Включает генерацию прерывания от звуковой платы при поступлении нового

MIDI-события. Для этого необходимо:

1.        Установить обработчик прерывания.

2.        Выполнить команду 31h.

3.        В обработчике прерывания: прочитать MIDI-событие.

4.        В обработчике прерывания: подтвердить прерывание чтением из 22Eh и  

                записью 20h в контроллер прерываний.

5.        Выполнить команду 31h еще раз, чтобы отменить генерацию прерывания.

32h: прямое чтение MIDI-события с дельта временем (SB)

Выполняет чтение очередного MJDI-события и 24-битного дельта времени, то есть времени в микросекундах, наступившего после предшествующего MIDI-со­бытия. (Считываются данные в следующем порядке: младший байт времени, средний байт времени, старший байт времени, MIDI-команда.) Именно в виде последовательности MIDI-событий, перед каждым из которых указано дельта-время, и записывается музыка в MIDI-файлах.

32h: чтение MIDI-события с дельта временем с прерыванием (SB). Включает/выключает генерацию прерываний от звуковой платы аналогично ко­манде 31h, но при чтении MIDI-события передаются вместе с дельта временами, как в команде 32h.

34h: режим прямого доступа к UART (SB2).

Отключает DSP, после чего все команды записи/чтения в его порты (используя тот же механизм проверки готовности) рассматриваются как MIDI-события. Вы­вести DSP из этого режима можно только с помощью полной переинициализации.

37 h: режим прямого доступа к UART с прерыванием (SB2)

Переключает порты DSP на UART аналогично команде 34h, но каждый раз, ког­да новое MIDI-событие готово для чтения, вызывается прерывание звуковой платы.

38h: MIDI прямая запись MIDI (SB).

 Посылает одно MIDI-событие.

40 h, ТС: установить временную константу (SB)

Устанавливает частоту оцифровки, используя однобайтную константу, рассчиты­ваемую следующим образом:

ТС = 256 - (1000000 / (число_каналов * частота)), где число_каналов - 1 для моно и 2 для стерео.

41h, LO, HI: установить частоту оцифровки (SB16)

Аналогично 40h, но указывается истинное значение частоты (сначала младший, потом старший байты). Число каналов определяется автоматически. Реальная частота тем не менее округляется до ближайшего возможного значения ТС.

45h: продолжить остановленное 8-битное воспроизведение через DMA (SB16) Продолжает остановленное командой 0DAh воспроизведение 8-битного звука через DMA с автоинициализацией.

47h: продолжить остановленное 16-битное воспроизведение через DMA (SB16). Продолжает остановленное командой 0D9h воспроизведение 16-битного звука через DMA с автоинициализацией.

48h, LO, HI: установить размер буфера DMA (SB2)

Устанавливает число байтов минус один для следующей команды передачи через DMA (сначала младший байт, затем старший).

74h, LO, HI: прямое воспроизведение 4-битного ADPCM через DMA (SB).

 Аналог 16h, но используется 4-битный вариант формата Creative ADPCM.

75h, LO, HI: прямое воспроизведение 4-битного ADPCM через DMA с новым ну­левым байтом (SB).

 Аналог 17h, но используется 4-битный вариант формата Creative ADPCM.

76h, LO, HI: прямое воспроизведение 2,6-битного ADPCM через DMA (SB).

 Аналог 16h, но используется 2,6-битный вариант формата Creative ADPCM.

77h, LO, HI: прямое воспроизведение 2,6-битного ADPCM через DMA с новым нулевым байтом (SB).

Аналог 17h, но используется 2,6-битный вариант формата Creative ADPCM.

7Dh: воспроизведение 4-битного ADPCM через DMA с автоинициализацией (SB2).

 Аналог lFh, но используется 4-битный вариант формата Creative ADPCM.

7Fh: воспроизведение 2,6:битного ADPCM через DMA с авто инициализацией (SB2).

 Аналог 1Fh, но используется 2,6-битный вариант формата Creative ADPCM.

80h, LO, HI: заглушить DSP (SB)

Вывести указанное число байтов тишины с текущей частотой оцифровки. 

0B?h/0C?h MODE, LO, HI: обобщенный интерфейс к DSP (SB16)

Команды 0B?h используются для 16-битных операций, команды 0C?h – для 8-битных. Младшие четыре бита определяют режим:

бит 0: всегда 0

бит 1: используется FIFO

бит 2: используется автоинициализация DMA

бит 3: направление передачи (0 - воспроизведение, 1 - оцифровка)

Аргументы этой команды - режим, младший байт длины, старший байт дли­ны (перед указанной командой не требуется устанавливать размер DMA-буфера специально)

В байте режима определены всего два бита (остальные должны быть равны нулю):

бит 4: данные рассматриваются как числа со знаком

бит 5: режим стерео

Длина во всех случаях равна числу байтов минус один для 8-битных операций и числу слов минус один для 16-битных.                                                                                  

0D0h: остановить 8-битную DMA-операцию (SB)

Останавливает простую (без автоинициализации) 8-битиую DMA-операцию.

0D1h: включить динамик (SB)

Разрешает работу выхода на динамик (колонки и т. д.).

После сброса DSP этот канал выключен.

0D3h: выключить динамик (SB)

Отключает выход на динамик (колонки и т.д.).

0D4h: продолжить 8-битную DMA-операцию (SB) Продолжает DM А-операцию, остановленную командой 0D0h.

0D5h: остановить 16-битную DMA-операцию (SB)

Останавливает простую (без автоинициалнзаци и) 16-битную DMA-операцию.

0D6h: продолжить 16-битную DMA-операцию (SB).

Продолжает DMA-операцию, остановленную командой 0D5h.

0D8h: определить состояние динамика (SB).

Возвращает 00h, если динамик выключен; 0FFh, если включен.

0D9h: завершить 16-битную DMA-операцию с автоинициализацией (SB16).

 Эта команда завершает операцию только после окончания воспроизведения теку­щего блока. Для немедленного прекращения воспроизведения необходимо выпол­нить последовательно команды 0D3h, 0D5h, 0D9h и 0D5h.

0DAh: завершить 8-битную DMA-операцию с автоиницианизацией (SB2) Аналог 0D9h, но для 8-битных операций.

0E0h, BYTE: проверка наличия DSP на этом порту (SB2)

Любой байт, посланный как аргумент к этой команде, возвращается при чтении из DSP в виде своего побитового дополнения (DSP выполняет над ним операцию NOT).

0E1h: определение номера версии DSP (SB) Возвращает последовательно старший и младший номера версии DSP:

1.? – SB

2.0 - SB2

3.0 - SBPro

3? - SBPro2

4.0? - SB16

4.11-SB16 SCSI-2

4.12 - AWE32

0E3h: чтение Copyright DSP (SBPro2)

Возвращает ASCIZ-строку с информацией Copyright данной платы.

0E4h, BYTE: запись в тестовый регистр (SB2)

Помещает байт в специальный неиспользуемый регистр, который сохраняется даже после переинициализацию DSP.

0E8h: чтение из тестового регистра (SB2)

Возвращает байт, помещенный ранее в тестовый регистр командой 0E1h 0F0h: генерация синусоидального сигнала (SB)

Запускает DSP на воспроизведение синусоидального сигнала с частотой около 2 кГц, который можно прервать только сбросом DSP.

0F2h: запрос на прерывание в 8-битном режиме (SB)

Генерирует прерывание от звуковой карты. В качестве подтверждения от обработ­чика ожидается чтение из порта 22Еh.

0F3h: запрос на прерывание в 16-битном режиме (SB)

Генерирует прерывание от звуковой карты. В качестве подтверждения от обработ­чика ожидается чтение из порта 22Fh.

 0FBh: состояние PSP (SB16) Возвращает байт состояния текущей DSP-операции:

           бит 0: 8-битное воспроизведение через DMA   

           бит 1: 8-битное чтение через DMA

           бит 2: 16-битное воспроизведение через DMA

           бит 3: 16-битное чтение через DMA

           бит 4: динамик включен

           биты 5-6: не определены

           бит 7: ТС модифицирована (может быть ноль, если предыдущая команда 40h пыталась  

                      установить неподдерживаемую частоту)

0FCh: дополнительная информация (SB16).

Возвращает дополнительный байт состояния текущей DMA-операции:

бит 1: синхронный режим (одновременная запись и воспроизведение)

бит 2:8-битный режим с автоинициализацией

бит 4: 16-битный режим с автоинициализацией

0FDh: последняя выполненная команда (SB16).

 Возвращает последнюю успешную команду DSP.

Программирование  контроллера DMA

Контроллер DMA используется для обмена данными между внешними уст­ройствами и памятью. Он нужен в работе с жесткими дисками и дисководами, звуковыми платами и другими устройствами, работающими со значительными объемами данных. Начиная с PC AT, в компьютерах присутствуют два DMA-контроллера - 8-битный (с каналами 0,1,2 и 3) и 16-битный (с каналами 4, 5, 6 и 7). Канал 2 используется для обмена данными с дисководами, канал 3 - для жестких дисков, канал 4 теряется при каскадировании контроллеров, а назначение осталь­ных каналов может варьироваться.

DMA позволяет выполнить чтение или запись блока данных, начинающегося с линейного адреса, который описывается как 20-битное число для первого DMA-контроллера и как 24-битное для второго, то есть данные для 8-битного DMA должны располагаться в пределах первого мегабайта памяти, а для второго - в пределах первых 16 Мб. Старшие четыре бита для 20-битных адресов и старшие 8 бит для 24-битных адресов хранятся в регистрах страниц DMA, адресуемых через порты 80h - 8Fh:

порт 81h: страничный адрес для канала 2 (биты 3-0 = биты 19-16 адреса)

порт 82h страничный адрес для канала 3 (биты 3-0 = биты 19-16 адреса)

порт 83h: страничный адрес для канала 1 (биты 3-0 = биты 19-16 адреса)

порт 87h: страничный адрес для канала 0 (биты 3-0 = биты 19-16 адреса)

порт 89h: страничный адрес для канала 6 (биты 7-0 = биты 23-17 адреса)

порт 8Аh: страничный адрес для канала 7 (биты 7-0 = биты 23-17 адреса)

порт 8Bh: страничный адрес для канала 5 (биты 7-0 = биты 23-17 адреса)

    Страничный адрес определяет начало 64/128-килобайтного участка памяти, с которым будет работать данный канал, поэтому при передаче данных через DMA обязательно надо следить за тем, чтобы не было выхода за границы этого участка, то есть чтобы не было попытки пересечения адреса 1000h:0, 2000h:0, 3000h:0 для первого DMA или 2000h:0, 4000h:0, 6000h:0 для второго.

Младшие 16 бит адреса записывают в следующие порты:

00h: биты 15-0 адреса блока данных для канала 0

01h: счетчик переданных байт канала 0

02h - 03 h: аналогично для канала 1

04h - 05h: аналогично для канала 2

06h - 07h: аналогично для канала 3

(для этих портов используются две операции чтения/записи - сначала пере­даются  

 биты 7-0, затем биты 15-8)

0C0h: биты 8-1 адреса блока данных для канала 4 (бит 0 адреса всегда равен нулю)

0C1h: биты 16-9 адреса блока данных для канала4

0С2 h: младший байт счетчика переданных слов канала 4

0C3h: старший байт счетчика переданных слов канала 4

0C4h - 0C7h: аналогично для канала 5

0C8h - 0CBh: аналогично для канала 5

0CCh - 0CFh: аналогично для канала 5

(эти порты рассчитаны на чтение/запись целыми словами)

Каждый из указанных двух DMА-контроллеров также имеет собственный на­бор управляющих регистров - регистры первого контроллера адресуются через порты 08h - 0Fh, а второго - через 0D0 - 0DFh:

порт 08h/0D0h для чтения: регистр состояния DMA

бит 7, 6,5, 4: установлен запрос на DMA на канале 3/7, 2/6,1/5,0/4

бит 3, 2, 1, 0; закончился DMA на канале 3/7, 2/6, 1/5, 0/4

порт 08h/D0h для записи: регистр команд DMA (устанавливается BIOS)

бит 7: сигнал DACK использует высокий уровень

бит 6: сигнал DREQ использует высокий уровень

бит 5: 1/0: расширенный/задержанный цикл записи

бит 4: 1/0: приоритеты сменяются циклически/фиксировано

бит 3: сжатие во времени

бит 2: DMА-контроллер отключен

бит 1: разрешен захват канала 0 (для режима память-память)

бит 0: включен режим память-память (канал 0 - канал 1)

порт O9h/0D2h для записи: регистр запроса DMA

бит 2: 1/0: установка/сброс запроса на DMA

биты 1-0: номер канала (00, 01, 10,11 - 0/4, 1/5, 2/6, 3/7)

порт 0Ah/0D4h для записи: регистр маски канала DMA

бит 2: 1/0: установка/сброс маскирующего бита

биты 1-0: номер канала (00,01, 10, И -0/4, 1/5,2/6,3/7)

порт 0Bh/OD6h для записи: регистр режима DMA

биты 7-6:

     00 - передача по запросу

     01 - одиночная передача (используется для звука)

     10 - блочная передача (используется для дисков)

     11 - канал занят для каскадирования

бит 5: 1/0: адреса уменьшаются/увеличиваются

бит 4: режим автоинициализации

биты 3-2:

       00  - проверка

       01 - запись

       10 - чтение

биты 1-0: номер канала (00, 01, 10, 11 - 0/4, 1/5, 2/6, 3/7)

порт 0Ch/0D8k для записи: сброс переключателя младший/старший байт

Для чтения/записи 16-биткых значений из/в 8-битные порты 00h-08h. Очередной байт, переданный в эти порты, будет считаться младшим, а сле­дующий за ним - старшим.

порт 0Dh/0DAh для записи: сброс контроллера DMA

Любая запись сюда приводит к полному сбросу DMA-контроллера, так что его надо инициализировать заново.

порт 0Dh/0DAh для чтения: последний переданный байт/слово.

порт 0Eh/0DCh для записи: любая запись снимает маскирующие биты со всех каналов

порт 0Fh/0DEh для записи: регистр маски всех каналов:

  биты 3-0: маскирующие биты каналов 3/7, 2/6, 1/5, 0/4

            Чаще всего внешнее устройство само инициализирует передачу данных, и все, что необходимо сделать программе, - это записать адрес начала буфера в порты, соответствующие используемому каналу, длину передаваемого блока данных ми­нус один в регистр счетчика нужного канала, установить режим работы канала и снять маскирующий бит.

Описание функции Open_file

open_file proc near

     mov  ax,3D00h ;Выполнить функцию DOS  3Dh: AH=3Dh,установим 

                     режим доступа AL=00 – открыть для чтения

                     

     mov  dx,offset filename ;Заносим в dx смещение filename и 

                               теперь в DS:DX –полный адрес ASCIZ-

                               строки с именем файла

     int  21h      ;Передать управление операц. системе и открыть  

                    файл для чтения

     jc   error_exit    ; если не удалось открыть файл,перейти на   

                           метку error_exit

     mov  bx,ax    ; заносим идентификатор файла в BX, 

                       необходимо для команды 42h

     mov ax,4200h ;Команда для перемещения указателя чтения/записи AH=42h,  

                    AL=0 – от начала файла

     mov  cx,0     ; CX:DX - новое значение указателя

     mov  dx,38h   ; по этому адресу начинаются данные в tada.wav

     int  21h      ; переместим файловый указатель 

     mov ah,3Fh        ; Чтение из файла AH=3Fh

     mov  cx,27459  ; считать 27459 байтов в файле tada.wav

     push ds        ;заносим считанные данные в стек

     mov dx,ds     

     and  dx,0F000h ; выровняем буфер на границу 4K-страницы

     add  dx,1000h ; складываем dx и 1000h, необход. для DMA

     mov  ds,dx

     mov  dx,0     ; DS:DX - адрес буфера

     int  21h      ; чтение файла

     pop  ds         ; выгрузить из стека данные в ds

     ret

error_exit:        ; если не удалось открыть файл

     mov  ah,9     ; AH=09h

     mov  dx,offset notopenmsg    ; DS:DX = адрес сообщения об 

                                  ; ошибке

     int  21h      ; вывод строки на экран

     int  20h      ; конец программы

notopenmsg    db   'Could not open file',0Dh,0Ah    ; сообщение об    

                                                  ; ошибке

         db   'Exiting',0Dh,0Ah,'$'

open_file endp

      Выход

      Начало
Алгоритм и блок-схема

   Инициализация

             DSP

1) В порт 226h записываем 1(начало инициализации)

2) Держим паузу не менее 3,3 мкс

3) В порт 226h записываем 0(конец инициализации)

4) Считываем порт 22Eh:

              если бит7=1, то можно считать с порта 22Ah;

              иначе повторить попытку 100 раз;

5) Считываем порт 22Ah:

              если значение=0AAh –D SP успешно  

                   инициализирован CF=0;

              иначе вернёмся к  пункту 4;

6) Через 100 попыток: если результат отрицательный, 

     значит DSP с портом 220h не существует CF=1.  

В bl заносим 0D1h – команда включить звук

Если CF=1

Если CF=0

не удалось считать


Функция dsp_write

посылает байт из bl в DSP

1) установить порт 22Ch;

2) Проверить готовность:

      - считываем и проверяем 7 бит

      - если значен. >0 – DSP готов к  

         записи

      - если знач. = 0 – повторить  

        попытку

3) Посылаем данные из bl в DSP

 

Считываем данные из файла
                                             

удалось считать

Перехватываем прерывание звуковой карты и разрешаем его

В bl заносим 40h – установить скорость передачи

В bl заносим 0B2h – определить  константу 11025/Stereo

DMA передача данных

1) Замаскируем канал 1(рабочий канал1)

2) Устанавливаем режим передачи (49h=48h+1, где 48h-команда установки буфера DMA, 1-номер используемого канала)

3) Запишем в порт 02h(канал 1) 16 младших бит адреса блока данных

4) Старшие 4 бита адреса записываем в порт 83h.

5) В порт 03h запис. длину данных минус 1.

6) Скинуть маску с канала 1.

7)Выполнить команду 14h – прямое воспроизведения 8-байтного PCM через DMA.

8) Отправляем на DSP младшие и старшие байты длинны проигрываемого участка минус 1.

Восстановить прерывание


Компиляция

Для  компиляции будем использовать компилятор и линковщик Tasm и Tlink соответственно:

            tasm /m wavdma.asm

            tlink /t /x wavdma.obj

Код исходной  программы(начало)

В этом примере задействован обычный DMA-режим работы, в котором зву­ковая плата проигрывает участок данных, вызывает прерывание и, пока обра­ботчик прерывания подготавливает новый буфер данных, программирует DMA и звуковую плату для продолжения воспроизведения, проходит некоторое вре­мя, что может звучать как щелчок. Этого можно избежать, если воспользоваться режимом автоинициалиэации, позволяющим обойтись без остановок во время воспроизведения.

FILESPEC equ 'C:WINDOWSMEDIATADA.WAV'

SBPORT   equ 220h

SBIRQ    equ 5         ; только IRQ0-IRQ7

     .model   tiny

     .code

     .186

     org  100h          ; COM-программа

start:

     call dsp_reset      ; инициализация DSP

     jc   no_blaster

     mov  bl,0D1h       ; команда 0D1h

     call dsp_write      ; включить звук

     call open_file      ; прочитать файл в буфер

     call hook_sbirq    ; перехватить прерывание

     mov  bl,40h        ; команда 40h

     call dsp_write      ; установка скорости передачи

     mov  bl,0B2h       ; константа для 11025Hz/Stereo

     call dsp_write

     call program_dma   ; начнём DMA-передачу данных

main_loop:              ; основной цикл

     cmp  byte ptr finished_flag,0

     je  main_loop      ; выход когда байт finished_flag = 1

     call restore_sbirq ; восстановить прерывание

no_blaster:

     ret

old_sbirq dd   ?         ; адрес старого обработчика

finished_flag db   0    ; флаг окончания работы

filename db   FILESPEC,0    ; имя файла

; обработчик прерывания звуковой карты

; устанавливает флаг finished_flag в 1

sbirq_handler proc far

     push ax

     mov  byte ptr cs:finished_flag,1 ; установить флаг

     mov  al,20h        ; послать команду EOI

Код исходной  программы(продолжение)

     out 20h,al        ; в контроллер прерываний

     pop  ax

     iret

sbirq_handler endp

; процедура dsp_reset

; сброс и инициализация DSP

dsp_reset proc near

     mov  dx,SBPORT+6 ; порт 226h - регистр сброса DSP

    

        mov  al,1 ; запись в него единицы запускает инициализацию

     out  dx,al

     mov  cx,40      ; небольшая пауза

dsploop:

     in   al,dx

     loop dsploop

     mov  al,0        ; запись нуля завершает инициализацию

     out  dx,al      ; теперь DSP готов к работе

     add  dx,8        ; порт 22Eh - бит 7 при чтении указывает на  

                        занятость

     mov  cx,100     ; буфера записи DSP

check_port:

     in   al,dx      ; прочитаем состояние буфера записи

     and  al,80h     ; если бит 7 ноль

     jz   port_not_ready     ; порт ещё не готов

     sub  dx,4        ; иначе: порт 22Ah - чтение данных из DSP

     in   al,dx

     add  dx,4        ; порт снова 22Eh

     cmp  al,0AAh   ; проверим, что DSP возвращает 0AAh при   

                      ; чтении -  это сигнал его готовности к   

                      ; работе

     je   good_reset

port_not_ready:

     loop check_port  ; повторить проверку на 0AAh 100 раз

bad_reset:

     stc             ; если Sound Blaster не откликается

     ret             ; вернуться с CF=1

good_reset:

     clc             ; если инициализация прошла успешно

     ret             ; вернуться с CF=0

dsp_reset endp

; процедура dsp_write

; посылает байт из BL в DSP

dsp_write proc near

     mov  dx,SBPORT+0Ch ; порт 22Ch - ввод данных/команд DSP

write_loop:          ; подождём готовности буфера записи DSP

     in   al,dx      ; прочитаем порт 22Ch

Код исходной  программы(продолжение)

    

     and al,80h     ; и проверим бит 7

     jnz  write_loop  ; если он не ноль - подождём ещё

     mov  al,bl      ; иначе:   

     out dx,al      ; пошлём данные

     ret

dsp_write endp

; процедура hook_sbirq

; перехватывает прерывание звуковой карты и разрешает его

hook_sbirq proc    near

     mov  ax,3508h+SBIRQ     ; AH=35h, AL=номер прерывания   

     int 21h      ; получим адрес старого обработчика

     mov  word ptr old_sbirq,bx   ; и сохраним его

     mov  word ptr old_sbirq+2,es

     mov  ax,2508h+SBIRQ     ; AH=25h, AL=номер прерывания

     mov  dx,offset sbirq_handler ; установим новый обработчик

     int  21h

     mov  cl,1

     shl  cl,SBIRQ

     not  cl       ; построим битовую маску

     in   al,21h        ; прочитаем OCW1

     and  al,cl         ; разрешим прерывание

     out  21h,al        ; запишем OCW1

     ret

hook_sbirq endp

; процедура restore_sbirq

; восстановим обработчик и запретим прерывание

restore_sbirq proc near

     mov  ax,3508h+SBIRQ     ; AH=25h AL=номер прерывания

     lds  dx,dword ptr old_sbirq

     int  21h      ; восстановим обработчик

     mov  cl,1

     shl  cl,SBIRQ ; построим битовую маску

     in   al,21h        ; прочитаем OCW1

     or   al,cl         ; запретим прерывание

     out 21h,al        ; запишем OCW1

     ret

restore_sbirq endp

; процедура open_file

; открывает файл filename и копирует звуковые данные из него, ;считая что  это - tada.wav, в буфер buffer

open_file proc near

     mov  ax,3D00h ; AH=3Dh AL=00

     mov  dx,offset filename ; DS:DX - ASCIZ-строка с именем файла

     int  21h      ; открыть файл для чтения

     jc   error_exit    ; если не удалось открыть файл - выйти

     mov  bx,ax         ; идентификатор файла в BX

Код исходной  программы(продолжение)

     mov ax,4200h ; AH=42h, AL=0

     mov  cx,0     ; CX:DX - новое значение указателя

     mov  dx,38h   ; по этому адресу начинаются данные в tada.wav

     int  21h      ; переместим файловый указатель 

     mov ah,3Fh        ; AH=3Fh

     mov  cx,27459  ; это - длина данных в файле tada.wav

     push ds

     mov dx,ds

     and  dx,0F000h ; выровняем буфер на границу 4K-страницы

     add  dx,1000h ; для DMA

     mov  ds,dx

     mov  dx,0     ; DS:DX - адрес буфера

     int  21h      ; чтение файла

     pop  ds

     ret

error_exit:        ; если не удалось открыть файл

     mov  ah,9     ; AH=09h

     mov  dx,offset notopenmsg    ; DS:DX = адрес сообщения об  

                                  ; ошибке

     int  21h      ; вывод строки на экран

     int  20h      ; конец программы

notopenmsg    db   'Could not open file',0Dh,0Ah    ; сообщение об     

                                                  ; ошибке

         db   'Exiting',0Dh,0Ah,'$'

open_file endp

; процедура program_dma

; настраивает канал 1 DMA

program_dma proc near

     mov  al,5      ; замаскируем канал 1

     out  0Ah,al

     xor  al,al    ; обнулим счётчик

     out  0Ch,al

     mov  al,49h   ; установим режим передачи

                   ; (используйте 59h для автоинициализации)

     out  0Bh,al

     push cs

     pop  dx

     and  dh,0F0h

     add  dh,10h   ; вычислим адрес буфера

     xor  ax,ax

     out  02h,al   ; запишем младшие 8 бит

     out  02h,al   ; запишем следующие 8 бит

     mov  al,dh

     shr  al,4

     out  83h,al   ; запишем старшие 4 бита

     mov  ax,27459 ; длина данных в tada.wav

     dec  ax       ; DMA требует длину-1

Код исходной  программы(заключение)

     out 03h,al   ; запишем младшие 8 бит длины

     mov  al,ah

     out  03h,al   ; запишем старшие 8 бит длины   

     mov al,1

     out  0Ah,al   ; снимем маску с канала 1 

     mov bl,14h   ; команда 14h

     call dsp_write ; 8-битное простое DMA-воспроизведение

     mov  bx,27459 ; размер данных в tada.wav

     dec  bx       ; минус 1

     call dsp_write ; запишем в DSP младшие 8 бит длины

     mov  bl,bh

     call dsp_write ; и старшие

     ret

program_dma endp

     end  start

Заключение

С момента рождения языка Assembler прошло много времени, появились новые языки и в особенности языки высокого уровня. И казалось бы что такой неудобный, грамосткий, трудно отлаживаемый язык Assembler исчезнет на всегда. Но время показало обратное – он до сих пор пользуется большой популярностью. Ведь благодаря ему можно написать высоко скоростной код, использующий полностью возможности операционной системы, взаимодействовать с внешними устройствами на уровне портов и многое другое.  Программирование современных звуковых плат – весьма сложное занятие, требующее уверенное владение языком. В данной работе я попытался описать и показать методы работы со звуковой картой.

Литература

1) Assembler для DOS, Windows и UNIX. – Зубков С.В. ”ДМК” Москва 2000г.

2) Искусство программирования на Ассемблере. – Голубь Н.Г. ”DiaSoft” 2002г.

3) Ассемблер для Windows. – Пирогов В.Ю. 2002г.

4) Windows Assembly Language and Systems Programming.- Barry Kauler.  (перевод).

5) Секреты системного программирования в Windows 98. - Мэтт Питрек.  К., 1996

6) Сайт www.wasm.ru.